LE-5150
10 CLEAR SCREEN
20 DIM Str$[255]
30 INTEGER I,Ch,Nop,Count
40 GOSUB Fileopen
50 ASSIGN @Load TO 702 !KG LE-5150-02 load
60 T0=TIMEDATE
70 !!!!!!!!!!!!!!!!!!!!!!!!!!!!!
80 ASSIGN @Ps TO 705 !6035 500V 5A
90 ! Ps_type=6035
100 Ps_type=66311
110 SELECT Ps_type
120 CASE 6035
130 OUTPUT @Ps;"VSET 50"!100V
140 OUTPUT @Ps;"ISET 3.1"!3A
150 CASE 66311
160 OUTPUT @Ps;"VOLT 15"!max 15V
170 OUTPUT @Ps;"CURR 3" !max 3A
171 OUTPUT @Ps;"OUTP ON"
180 END SELECT
190 !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
200 Str$="채널1을 사용합니다."
210 DIALOG "INFORMATION",Str$,Btn
220 Ch=1
230 Offset_volt=0
240 OUTPUT @Load;"CV";Ch;",";Offset_volt;",0"
250 R_max=1000 !최대 1000
260 R_min=10 !최소 10
270 Nop=201
280 OUTPUT @File;"No., Time[s], Load R[ohm], Ps-V[V], Ps-I[A], Load V[V], Load I[V], Load P[W]"
290 !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
300 Str$="로드에 연결하십시요."
310 DIALOG "INFORMATION",Str$,Btn
320 OUTPUT @Load;"LD";Ch;",1" ! LOAD ON
330 OUTPUT @Load;"CR";Ch;",";R_min;",0" !첫번째 측정에 문제가 있어
340 WAIT 1
350 Count=0
360 T0=TIMEDATE
370 LOOP
380 Count=Count+1
390 R_step=(R_max-R_min)/(Nop-1)
400 R=R_max-R_step*(Count-1)
410 OUTPUT @Load;"CR";Ch;",";R;",0"
420 GOSUB Ps_reading
430 GOSUB Load_reading
440 Power=Volt*Curr
450 PRINT "No.=";Count;" Set R=";R;" V=";Volt;" I=";Curr;" P=";Power
460 T=TIMEDATE-T0
470 OUTPUT @File;Count,T,R,Volt_ps,Curr_ps,Volt,Curr,Power
480 EXIT IF Count=Nop
490 EXIT IF Curr>3
500 EXIT IF Power>150
510 END LOOP
520 OUTPUT @Load;"LD";Ch;",0" ! LOAD OFF
530 STOP
540 RETURN
550 Fileopen: !
560 DIM Filename$[20],Dhms$[8]
570 Time$=TIME$(TIMEDATE)
580 Date$=DATE$(TIMEDATE)
590 Dhms$=Date$[1;2]&Time$[1;2]&Time$[4;2]&Time$[7;2]
600 Filename$=Dhms$&".txt"
610 CREATE Filename$,1
620 ASSIGN @File TO Filename$;FORMAT ON
630 RETURN
640 Ps_reading: !
650 SELECT Ps_type
660 CASE 6035
670 OUTPUT @Ps;"VOUT?" !volt
680 ENTER @Ps;Readv$
690 Volt_ps=VAL(Readv$[5;7])
700 OUTPUT @Ps;"IOUT?" !curr
710 ENTER @Ps;Readi$
720 Curr_ps=VAL(Readi$[5;7])
730 CASE 66311
740 OUTPUT @Ps;"MEAS:VOLT?" !volt
750 ENTER @Ps;Volt_ps
760 OUTPUT @Ps;"MEAS:CURR?" !curr
770 ENTER @Ps;Curr_ps
780 END SELECT
790 RETURN
800 Load_reading: !
810 SELECT Count
820 CASE 1
830 FOR I=1 TO 10
840 OUTPUT @Load;"MG";Ch;",1"!volt
850 ENTER @Load;Volt
860 OUTPUT @Load;"MG";Ch;",2"!curr
870 ENTER @Load;Curr
880 NEXT I
890 CASE ELSE
900 OUTPUT @Load;"MG";Ch;",1"!volt
910 ENTER @Load;Volt
920 OUTPUT @Load;"MG";Ch;",2"!curr
930 ENTER @Load;Curr
940 END SELECT
950 RETURN
960 END