4338-01.txt

4338B 밀리오옴미터

10     !Agilent 4338B milliohmmeter
20     INTEGER I,Stat,Count
30     GOSUB Fileopen
40     ASSIGN @Lowr TO 716
50     OUTPUT @Lowr;"*IDN?"
60     ENTER @Lowr;Id$
70     PRINT Id$
80    !STOP
90    !OUTPUT @Lowr;"*RST;*CLS"
100    OUTPUT @Lowr;":INIT:CONT ON"  ! Initiating trigger system
110    OUTPUT @Lowr;":CALC1:FORM REAL" ! Primary parameter: REAL,MLINear(absolute value of impedance) 중 택일
120    OUTPUT @Lowr;":CALC2:FORM IMAG"! Secondary parameter: NONE, IMAG, LS, PHAS 중 택일
130    OUTPUT @Lowr;":SOUR:CURR:AUTO ON" ! Test Signal Level = auto level mode
140    OUTPUT @Lowr;":TRIG:SOUR BUS" ! Trigger source: Bus
150    Count=0
160    T0=TIMEDATE
170    !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
180    Meas_type=1   ! 1:샘플이 꼽히면 측정  2:무조건 측정
190    !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
200    SELECT Meas_type
210    CASE 2
220      OUTPUT @File;"No.,Time[m],R[ohm],Ls[uH]"
230      LOOP
240        Count=Count+1
250        GOSUB Reading
260        T=TIMEDATE-T0
270        T=T/60.
280        PRINT Count,A,B
290        OUTPUT @File;Count,T,A,B
300        OUTPUT @Lowr;":SYST:BEEP"
310      END LOOP 
320    CASE 1
330      OUTPUT @File;"No., R[ohm], Ls[uH]"
340      LOOP
350   !샘플이 꼽혔나?
360        REPEAT
370          GOSUB Reading
380        UNTIL A>.01 AND A<20
390        Count=Count+1
400        FOR I=1 TO 2
410          GOSUB Reading
420        NEXT I
430        PRINT Count,A,B
440        OUTPUT @File;Count,A,B
450        OUTPUT @Lowr;":SYST:BEEP"
460   !샘플이 빠져 있나?
470        REPEAT
480          GOSUB Reading
490        UNTIL A>100
500      END LOOP 
510    CASE 2
520    END SELECT 
530    STOP
540 Reading:   !
550    OUTPUT @Lowr;"*TRG"
560    ENTER @Lowr;Stat,A,B
570    A=A*1
580    B=B*1
590    RETURN
600 Fileopen:  !
610    DIM Filename$[20],Dhms$[8]
620    Time$=TIME$(TIMEDATE)
630    Date$=DATE$(TIMEDATE)
640    Dhms$=Date$[1;2]&Time$[1;2]&Time$[4;2]&Time$[7;2]
650    Filename$=Dhms$&".txt"
660    CREATE Filename$,1
670    ASSIGN @File TO Filename$;FORMAT ON
680    RETURN
690    END